Unvisibility Sketch & Work Feature With VBA or iLogic Oleh Ihsan Surahman

Terkadang saat kita membuat model, kita sering membuat sketchs (Sketch/3D Sketch) dan work feature (Custom Axis, Plane & Point) untuk membentuk 3D model lebih baik. Tapi terlupa untuk men "Un" visibilitykan sketch dan work feature tersebut. Lihat Gambar: Visibility.jpg.

Visibility.jpg

Inventor memang sudah menyediakan Tool Object Visibility di part atau assembly modeling.
Lihat Gambar: Object visibility.png

Visibility.png

Tapi yang sebenarnya Tool ini hanya sementara men "Un" visibility kan. Bila kita cek, sketch dan work feature tersebut masih ter Visibility secara sistem.

Disini saya menggunakan VBA macro yang tersedia di Inventor itu sendiri untuk memudahkan men "Un" visibility sketch dan Work Features tersebut.

Dengan mengakses, Lihat Gambar:Macro Windows.jpg

Macro Windows.jpg

1. Pilih menu Tools,
2. Di ribbon Option, pilih menu VBA Editor

Di Microsoft Visual Basic for Applications window:
3. Di Project Explorer, terdapat ApplicationProject dan didalamnya terdapat Module1.
4. Klik kanan di Module1 > View Code.
5. Di blank code ini lah kita dapat membuat perintah2 kecil.

6. Create code, berikut penjelasannya:

-------------------------------------------------------
Public Sub UnvisibilitySketchWorkFeatures()
End Sub

Disini kita membuat suatu perintah macro dengan nama UnvisiblitySketchWorkFeatures.

-------------------------------------------------------
Public Sub UnvisiblitySketchWorkFeatures()
   Dim oApp As Application
   Dim oPD As PartDocument
   Dim oPCD As PartComponentDefinition
 
   Set oApp = ThisApplication
   Set oPD = oApp.ActiveDocument
   Set oPCD = oPD.ComponentDefinition
End Sub

Fungsi dim disini adalah mendeklarasikan nama singkatan yang menurut kita cocok digunakan/mudah di ingat bila nama tersebut kita gunakan kembali.

fungsi Set adalah menetapkan bahwa nama variable yang sebelumnya sudah kita deklarasikan untuk digunakan, di set ke suatu object library Inventor (Thisapplication, PartDocument, PartComponentDefinition, etc). Bila kita menggunakan iLogic atau Visual Basic, kita tidak perlu lagi menggunakan kata "set" saat menetapkan nama deklarasi ke object library Inventor.

contoh:

Dim oPD as PartDocument
set oPD = oApp.ActiveDocument

Dari code diatas oPD hanya di set untuk part document saja, dan secara umum perintah macro UnvisibilitySketchWorkfeatures ini hanya untuk part Document saja.

-------------------------------------------------------
Public Sub UnvisiblitySketchWorkFeatures()
   Dim oApp As Application
   Dim oPD As PartDocument
   Dim oPCD As PartComponentDefinition
   Dim oSkt As Sketch
   Dim oWp As WorkPlane
   Dim oWa As WorkAxis
   Dim oWPo As WorkPoint
   Set oApp = ThisApplication
   Set oPD = oApp.ActiveDocument
   Set oPCD = oPD.ComponentDefinition
   For Each oSkt In oPCD.Sketches
       oSkt.Visible = False
   Next
 
   For Each oWp In oPCD.WorkPlanes
       oWp.Visible = False
   Next
 
   For Each oWa In oPCD.WorkAxes
       oWa.Visible = False
   Next
 
   For Each oWPo In oPCD.WorkPoints
       oWPo.Visible = False
   Next
End Sub

Fungsi For Each....Next Statement adalah mencari object dan melakukan suatu procedure dari item 1 hingga terakhir dari suatu kumpulan object, secara sistem indeks Work Plane pertama adalah YZ Plane, dan item terakhir Work Plane adalah sesuai work plane yang kita buat terakhir.

procedurenya adalah oWP.visibility = False, bila ada workplane yang masih ter Visibility, maka akan di Un-Visibility.

Untuk final codenya akan seperti pada Gambar:Final Code.jpg

Final Code.jpg

NOTE: perintah macro ini hanya bisa dijalankan di part document, dan bila ingin di pindahkan ke iLogic Rule sebagai External Rule, silahkan Copy/Paste code ini, dan Hapus baris Public Sub..End Sub dan hapus kata "Set". Lihat Gambar: Final Code In iLogic External Rule.jpeg

Final Code In iLogic External Rule.jpeg